🐮12 ERC系列标准

[TOC]

ERC系列标准

基于 ERC 系列标准开发可以建立在 OpenZeppelin 的基础上

• OpenZeppelin 是著名的安全智能合约开发库。建立在经过社区审查的代码的坚实基础之上。

• ERC20 和 ERC721 等标准的实施。

• 灵活的基于角色的许可方案。

• 可重用的 Solidity 组件，用于构建自定义合约和复杂的去中心化系统。

• 文档 https://docs.openzeppelin.com

• 源码 https://github.com/OpenZeppelin

ERC20 代币标准

ERC20 是2015年提出的一个能实现智能合约中代币的 API 标准。

• ERC-20 提供一个同质化代币的标准，是以太坊上的一个代币协议，所有基于以太坊开发的代币合约都遵守这个协议，遵守协议的代币可以被各种以太坊钱包支持，用于不同的平台和项目。

• 它提供了多个功能。例如转账代币从一个帐户到不同的帐户，来实现获取帐户的当前余额以及网络上的可用代币总供应量。

函数和事件

如果智能合约实施了下列函数和事件，它可以被称为 ERC-20 代币合约， 部署后负责跟踪以太坊上创建的代币。

• 一共 4 个getter函数，5个转账相关函数，2个事件。

• 授权函数 approve ，用户授权一个额度给_spender，_spender这个用户可以多次使用这个额度，如使用 transferFrom 函数将 _from 授权给 _spender 的额度发送给 _to，也可以通过 allowance 函数查询 _owner 授权给 _spender的剩余额度。

• ERC20 文档 https://eips.ethereum.org/EIPS/eip-20 。

函数

// 状态变量，自动生成getter函数
// name 代币（token）名称
function name() public view returns (string)

// symbol 代币简称
function symbol() public view returns (string)

// decimals 返回token使用的小数点后几位。比如如果设置为3，就是支持0.001。一般为18位。
function decimals() public view returns (uint8)

// totalSupply token总供应量
function totalSupply() public view returns (uint256)

// 函数
// balanceOf 显示地址为_owner的账户余额。
function balanceOf(address _owner) public view returns (uint256 balance)

// transfer 发送_value数量的token给地址_to。
function transfer(address _to, uint256 _value) public returns (bool success)

// transferFrom 从地址_from发送_value数量的token给地址_to。
function transferFrom(address _from, address _to, uint256 _value) public returns (bool success)

// approve _spender 从用户账户里多次提取额度_value数量的token，函数再次被调用后一次的授权额度会重置前一次的授权。
function approve(address _spender, uint256 _value) public returns (bool success)

// allowance 返回 _spender 可从 _owner 提取token数量。
function allowance(address _owner, address _spender) public view returns (uint256 remaining)

事件

// Transfer Token被传输时会触发
event Transfer(address indexed _from, address indexed _to, uint256 _value)

// Approval approve 函数被调用时触发
event Approval(address indexed _owner, address indexed _spender, uint256 _value)

ERC20 标准智能合约发行代币

IERC20.sol

• IERC20.sol 是介绍的一个接口源代码，可以通过实现这个接口快速发代币。

SafeMath.sol

• SafeMath.sol 是官方介绍的用于代币发行的代币计算相关函数库，它提供了对代币加减乘除计算的函数，一般使用 using SafeMath for uint256; 的方式使用。

• 在 https://github.com/OpenZeppelin/openzeppelin-contracts 可以找到库源码。

代币合约

• 代币合约可以参考 https://github.com/OpenZeppelin/openzeppelin-contracts/blob/9b3710465583284b8c4c5d2245749246bb2e0094/contracts/token/ERC20/ERC20.sol 。

扩展标准 ERC-165

扩展接口 ERC165 是用于标准接口检测，创建标准方法以发布和检测智能合约实现的接口。

• 目的是为了查询合约是否支持接口以及是否支持接口的版本，可以根据是否实现接口调整与合约的交互方式。

• 在此标准中，接口是由以太坊 ABI 定义的一组函数选择器。 这是Solidity的接口（ABI）概念子集，ABI接口还定义了返回类型，可变性（mutability）和事件。

• 通过函数选择器的函数签名(如："myMethod(uint256,string)")的 Keccak（SHA-3）哈希的前 4 字节识别是否实现了接口。

• 兼容 ERC-165 的合约只需实现 ERC165 接口的 supportsInterface 函数。

函数

// 查询合约是否实现了接口
// interfaceID 接口标识符， 调用gas不会超过 30000 wei
// true 如果合约实现了 interfaceID 并且 interfaceID 不为 0xffffffff，否则为 false。
function supportsInterface(bytes4 interfaceID) external view returns (bool);

计算接口标识符：

• 接口标识符是接口中所有函数选择器的异或（XOR）。

// SPDX-License-Identifier: GPL-3.0

pragma solidity ^0.8.0;

interface Solidity101 {
    function hello() external pure;
    function world(int) external pure;
}

contract Selector {
    function calculateSelector() public pure returns (bytes4) {
        Solidity101 i;
        // 所有函数选择器异或
        return i.hello.selector ^ i.world.selector;
    }
}

检测合约是否实现了 ERC-165

• 在合约地址上使用附加数据（input data）0x01ffc9a701ffc9a700000000000000000000000000000000000000000000000000000000 和 gas 30000 进行 STATICCALL 调用，相当于 contract.supportsInterface(0x01ffc9a7)。

• 如果调用失败或返回false , 说明合约不兼容ERC-165标准

• 如果返回true，则使用输入数据0x01ffc9a7ffffffff000000000000000000000000000000000000000000000000000000000000进行第二次调用。

• 如果第二次调用失败或返回true，则目标合约不会实现ERC-165。 否则它实现了ERC-165。

检测合约是否实现了某个接口

• 如果不确定合约是否实现ERC-165，请使用上面的方法进行确认。

• 如果没有实现ERC-165，那么你将不得不看看它采用哪种老式方法。

• 如果实现了ERC-165，那么只需调用 supportsInterface(interfaceID) 来确定它是否实现了对应的接口。

ERC-165 的实现

supportsInterface 的实现

• 例子中实现方式是在构造函数中将合约实现的接口的标识符存入 mapping ，supportsInterface 函数中通过查找 mapping 以确定是否实现了某些接口，每次执行查找成本都是 586 gas。 但合约初始化需要存储每个接口会消耗 gas。

• 也可以直接在 supportsInterface 中对接口进行比较确定是否实现接口，但是随着计算的接口越多支付的 gas 也会增加。

• 两种方式在 gas 消耗上差别较大。

// SPDX-License-Identifier: GPL-3.0

pragma solidity ^0.8.0;

interface ERC165 {
    function supportsInterface(bytes4 interfaceID) external view returns (bool);
}

interface A{
    function test1() external;
    function test2(uint num,uint num2) external returns(uint);
}

contract demo3 is A,ERC165{

    // mapping 用于保存接口的标识符
    mapping(bytes4 => bool) internal supportedInterfaces;

    constructor(){
        // 初始化将接口标识符存入 mapping
        supportedInterfaces[demo3.supportsInterface.selector] = true;
        supportedInterfaces[demo3.test1.selector ^ demo3.test2.selector] = true;
    }

    // 测试使用：获取实现的接口的标识符
    function getInterfaceId() public pure returns(bytes4,bytes4){
        return (demo3.supportsInterface.selector,demo3.test1.selector ^ demo3.test2.selector);
    }

    function test1() external view{}

    function test2(uint num,uint num2) external pure returns(uint){
        return num + num2;
    }

    function supportsInterface(bytes4 interfaceID) external view returns (bool){
        // 在mapping中找 interfaceID，未找到说明没实现返回false
        return supportedInterfaces[interfaceID];
    }
}

ERC-721 非同质化代币标准

ERC-721（Ethereum Request for Comments 721），是在 2018 年提出的一个在智能合约中实现代币 API 的非同质化代币标准。

• 非同质化代币（NFT）用于以唯一的方式标识某样物品。此类型的代币可以用于出售收藏品、密钥、彩票、音乐会座位编号、体育比赛等物品的平台。

• ERC-721 是为 NFT 引入的标准，这种类型的代币是独一无二的，并且可能与来自同一智能合约的另一代币有不同的价值，也许是因为它的年份、稀有性或是它的外观。

• 所有 NFT 都有一个 uint256 变量，名为 tokenId，所以对于任何 ERC-721 合约，这对值 contract address, tokenId 必须是全局唯一的。

• dApp 可以有一个“转换器”，该转换器使用 tokenId 输入和输出一些非常有趣的事物的图像， 例如蒙娜丽莎、武器、技能或一只宠物。

• ERC-721 提供了一些功能，例如将代币从一个帐户转移到另一个帐户、获取帐户的当前代币余额、获取代币的所有者、以及整个网络的可用代币总供应量。 除此之外，它还具有其他功能，例如批准帐户中一定数量的代币可以被第三方帐户转移。

函数和事件

智能合约实现了 ERC-721 规定的方法和事件，就可以被称为 ERC-721 非同质化代币合约。 部署后它负责跟踪在以太坊上创建的代币。

函数

//  _owner 拥有的 NFT 数量，可能为零
function balanceOf(address _owner) external view returns (uint256);

// NFT（_tokenId） 所有者的地址
function ownerOf(uint256 _tokenId) external view returns (address);

// 将 NFT _tokenId 的所有权从 _from 地址转移到 _to 地址
// 前提是_from有授权给操作者或操作者就是NFT的拥有者
function safeTransferFrom(address _from, address _to, uint256 _tokenId) external payable;

// safeTransferFrom 的重载函数
// data： 没有指定格式的附加数据，在调用 _to 时发送
function safeTransferFrom(address _from, address _to, uint256 _tokenId, bytes data) external payable;

// 转移 NFT _tokenId 的所有权到 _to，要确保 _to 能接收否则永久丢失NFT
// 前提是_from有授权给操作者或操作者就是NFT的拥有者
function transferFrom(address _from, address _to, uint256 _tokenId) external payable;

// 更改或重申 NFT _tokenId 的授权地址，新授权的地址
function approve(address _approved, uint256 _tokenId) external payable;

// 启用或禁用授权给 _operator 的NFT，_approved = 授权 true，取消 false
function setApprovalForAll(address _operator, bool _approved) external;

// 获取 NFT _tokenId 授权的地址，没有找到返回 address(0)
function getApproved(uint256 _tokenId) external view returns (address);

// 查询 _owner 是否授权 _operator 地址
// _operator 是 _owner 授权的返回 true，否则返回 false
function isApprovedForAll(address _owner, address _operator) external view returns (bool);

事件

//  当 NFT 的所有权通过任何机制发生变化时触发事件，被创建和销毁时也触发。
event Transfer(address indexed _from, address indexed _to, uint256 indexed _tokenId);
// 在 NFT 的批准地址更改时触发事件。
event Approval(address indexed _owner, address indexed _approved, uint256 indexed _tokenId);
// 当为所有者启用或禁用操作员时触发事件。
event ApprovalForAll(address indexed _owner, address indexed _operator, bool _approved);

扩展接口 ERC721TokenReceiver

扩展接口 ERC721TokenReceiver 的接口标识符是 0x150b7a02。

• 合约要接受 NFT 转账，就必须实现 ERC721TokenReceiver 接口。

interface ERC721TokenReceiver {
    // 合约处理 NFT _tokenId 的接收
    // _operator 操作从 _from 转账 NFT 到本合约
    function onERC721Received(address _operator, address _from, uint256 _tokenId, bytes _data) external returns(bytes4);
}

可选元数据扩展接口 ERC721Metadata

对于ERC-721 智能合约，元数据扩展接口是可选的。实现允许询问智能合约的名称以及 NFT 所代表的资产的详细信息。

• ERC721Metadata 的接口标识符是 0x5b5e139f。

• 接口用于提供合约的元数据：name , symbol 及 URI（NFT所对应的资源）。

• name、symbol 如果不具体实现则使用空字符串是有效的响应也比不实现好。任何智能合约都可以使用与合约相同的 name 和 symbol。

• ERC721Metadata 提供了一种将 NFT 与 URI 关联的机制。预计许多实现将利用这一点为每个 NFT 提供元数据。URI 可能是可变的。我们考虑了代表房屋所有权的 NFT，在这种情况下，关于房屋的元数据（图像、居住者等）可以自然地改变。

• 元数据作为字符串值返回。目前，这仅可用作调用 web3，而不是从其他合约调用。没有考虑过区块链应用程序会查询此类信息的用例。

• 考虑的替代方案：将每个资产的所有元数据放在区块链上（太昂贵），使用 URL 模板查询元数据部分（URL 模板不适用于所有 URL 方案，尤其是 P2P URL），multiaddr 网络地址（不够成熟）。

interface ERC721Metadata /* is ERC721 */ {
    // NFT集合名称，建议实现，即便是返回空字符串。
    function name() external view returns (string _name);
    
    // NFT集合简称，建议实现，即便是返回空字符串。
    function symbol() external view returns (string _symbol);
    
    // _tokenId 所对应的外部资源文件的URI，通常是IPFS或HTTPS路径。
    // URI可能指向一个符合“ERC721”的JSON文件，文件包含名字、描述、图片等
    // tokenURI通常是被web3.js调用，在应用层做相应的查询和展示。
    function tokenURI(uint256 _tokenId) external view returns (string);
}

元数据格式，这个元数据一般存储在 IPFS 上，但也有可能存放在私人服务器

{
    "title": "Asset Metadata",
    "type": "object",
    "properties": {
        "name": {
            "type": "string",
            "description": "NFT 代表什么的描述"
        },
        "description": {
            "type": "string",
            "description": "NFT 代表的资产的描述"
        },
        "image": {
            "type": "string",
            "description": "指向NFT表示资产的资源的URI（MIME 类型为 image/*）"
        }
    }
}

可选枚举扩展接口 ERC721Enumerable

ERC721Enumerable 的主要目的是提高合约中NTF的可访问性。

• ERC721Enumerable 的接口标识符 0x780e9d63。

interface ERC721Enumerable /* is ERC721 */ {
    // NFT总量。
    function totalSupply() external view returns (uint256);

    // 通过索引获取对应的tokenId。
    // 如果 _index >= totalSupply() 则抛出异常。
    function tokenByIndex(uint256 _index) external view returns (uint256);

    // 返回 _owner 拥有的NFT列表中对应索引的 tokenId。
    // 如果 _index >= balanceOf(_owner) 或者 _owner 是零地址，代表无效的 NFT。
    function tokenOfOwnerByIndex(address _owner, uint256 _index) external view returns (uint256);
}

ERC-721 的实现

实现 ERC-721 是发行 NFT 资产的智能合约

• 以图片为例，智能合约中并不负责存储图片，图片也不是存储在以太坊，图片存储在 IPFS 或其它地方（没有强制性规定），合约的重要功能是将图片所在地方与智能合约中的 _tokenId 相关联。

NFT 之坑

• 因为链本身不存储图片，如果存储图片的服务消失则持有者只能傻傻看着一个 tokenId 发愣。

• 如果存储扩展元数据的不是 IPFS 这类一经发布不可更改的服务，那么元数据的 JSON 文件的内容可能还是可变的，今天 tokenId 关联的是 林志玲艺术照 的元数据，明日可能被篡改关联到 xxx艺术照 甚至可能是 404 。

• 因此 NFT 具备的唯一性是一个假唯一性，并不是真正唯一。

例子中实现 ERC-721 并发行 NFT（图片） 步骤：

• 第一步：制作图片，并且图片用数字命名，这个名字与合约中的 tokenId 一致，上传图片到 IPFS。

• 第二步：写元数据扩展文件，一个图片对应一个扩展文件，文件名就是图片名的数字，不要有后缀，上传元数据扩展文件到 IPFS。

• 第三步：开始编写智能合约代码，主要结构遵循 openzeppelin 的 ERC-721 案例实现。

• 第四步：调用铸币函数开始铸币，就是将已经上传到 IPFS 的元数据扩展文件名 tokenId 存到区块链上，这个 tokenId 的持有者是合约拥有者。

• 第五步：配置一个 baseURI ，它是 IPFS 文件访问的前缀，确保 baseURI + tokenId 能够访问到元数据扩展文件，而 ERC721Metadata 接口的 tokenURI 函数的返回值就是 baseURI/tokenId。

• 第六步：正常转让交易 NFT，也可以在 opensea 查看。

引入的依赖所有源码在 https://github.com/OpenZeppelin/openzeppelin-contracts 下

• 一个最简单的 ERC-721 实现

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

import "https://github.com/OpenZeppelin/openzeppelin-contracts/blob/master/contracts/token/ERC721/presets/ERC721PresetMinterPauserAutoId.sol";

contract demo2PDMNFT is ERC721PresetMinterPauserAutoId {
    constructor()
        // 注意 baseURI 最后的 /
        ERC721PresetMinterPauserAutoId("PDM NFT EXAMPLE", "PDME", "ipfs://QmYB7P4WLNGxv4x8g5PBPS4sHtD5Q3cqDES7aWzHmM2YWE/")  
    {}
    
    // 这是 opensea 的 Contract-level metadata 
    function contractURI() public pure returns (string memory) {
        return "ipfs://QmRPdHNnzm9Xj5TMZ15p81t4xKPrLcCWW9nvpDnhKw6nyL";
    }
}

• 在这个 demo 中，合约部署完成后调用 mint(address to) 函数铸币，实际是产生一个未被使用的 tokenId 并且它归属 to，默认情况下 tokenId 从0开始。

• 这个 demo 中的铸币函数1次铸币一个，在正常业务中，还需根据业务需要增加或修改铸币函数，但是铸币其实负责的只是生成未被使用的 tokenId。

• 测试环境下访问 https://testnets.opensea.io/assets/ 查看测试铸造的 NFT

• 如访问 https://testnets.opensea.io/assets/0x85d969e9018a30e39dafd2d7b73f3d1bd0254b04/1

测试环境 NFT 访问

测试环境 NFT 访问

1号NFT的扩展元数据

• ipfs://QmYB7P4WLNGxv4x8g5PBPS4sHtD5Q3cqDES7aWzHmM2YWE/1

• 在不同平台支持的 NFT 元数据解析数据会有所差异，因此 ERC721Metadata 的元数据模板是一个基础的模板，opensea 的元数据格式参见 https://docs.opensea.io/docs/metadata-standards 。

{
    "title": "PandaManGFExample",
    "type": "object",
    "properties": {
        "name": {
            "type": "string",
            "description": "功夫熊猫人"
        },
        "description": {
            "type": "string",
            "description": "如来神掌"
        },
        "image": {
            "type": "string",
            "description": "ipfs://QmNtgo3ymuJdmh9eSBhnh7vtaG6fXqeiKUuet2vofx7GJ9/1.gif"
        }
    }
}

函数 contractURI() 的用途是集合描述扩展元数据文件的存放地址，如 ipfs://QmRPdHNnzm9Xj5TMZ15p81t4xKPrLcCWW9nvpDnhKw6nyL 的集合描述扩展元数据

• 集合元数据如 opensea 的格式在 https://docs.opensea.io/docs/contract-level-metadata ， name 集合名称，description 集合描述，image 集合封面图片的URI，external_link 外部连接生成环境改成 https://openseacreatures.io ，seller_fee_basis_points 是每次销售收取费率 1是万分之1 设置成100就是百分之1，fee_recipient 费率收取账户。

{
  "name": "熊猫人功夫系列",
  "description": "熊猫人联合武侠仙侠的功夫系列NFT",
  "image": "ipfs://QmW8qainyV37Xf46TewW3fkxSSd3BUfn3ic2oFjoaV4EF6",
  "external_link": "https://testnets.opensea.io",
  "seller_fee_basis_points": 1,
  "fee_recipient": "0x7ec9156b578508c9C03ee9C74Cfd5858A27D06D2"
}

集合描述的展示

集合描述的展示